; 1 meg version ported from 12 meg version of IR controller.
; copyright E.Matejowsky
; My website is currently at http://www.ozemail.com.au/~eddiema/
; My current email address is eddiema@ozemail.com.au
; I grant permission for use of my code or code fragments in non-commercial projects only.
;-----------------------------------------------------------------
.device	AT90S1200	;Prohibits use of non-implemented instructions

.nolist
.include "1200def.inc"	;I/O port and bit definitions
.list


.CSEG				
; working registers for the program.
.def	temp 	 =r16
.def	counter1 =r17	; counters for various timing routines.
.def 	counter2 =r18
.def 	counter3 =r19
.def	counter0 = r20
.def	matrixread = r21
.def	switches = r22

.def	grp1 = r23
.def	grp2 = r24
.def	grp3 = r25
.def	grp4 = r26

.def	codehi = r27	; code hi byte
.def	codelo = r28	; code hi byte

.def 	rectimer = r29	; recording timer
.def	loopcnt	= r30 ;
.def	cd1	= r31  ;
.def	cd2	= r22  ; reuse switch variable

.set	stmt     = pb0
.set	hdfullno = pb1


.MACRO	IRon			; Start macro definition
	sbi	PORTB,PB3	; turn fet on
.ENDMACRO						
.MACRO	IRoff			; Start macro definition
	cbi	PORTB,PB3	; turn fet on
.ENDMACRO						
.MACRO	LEDon	
	sbi	PORTB,PB6	; LED ON
.ENDMACRO						

.MACRO	LEDoff			; Start macro definition
	cbi	PORTB,PB6	; turn fet on
.ENDMACRO
.MACRO	LAMPSon	
	sbi	PORTD,PB3	; LED ON
.ENDMACRO						
.MACRO	LAMPSoff			; Start macro definition
	cbi	PORTD,PB3	; turn fet on
.ENDMACRO	

;Reset  vector (must be the first code generated)
	rjmp	RESET		;To Reset handler

;-----------------------------------------------------------------	

;delay routines, note all rountines use one level of stack (we can have 3 levels total)
DELAY:  ldi	temp,0		;Entry point for Max timer delay
DENTR:	out	TCNT0,temp	;Set the timer value.
  	ldi	temp,1<<TOIE0		;
	out	TIFR,temp	;Clear the timer overflow flag (by writing a 1 to it!)
WAIT1:	in	temp,TIFR	;Check for timer overflow
	sbrs	temp,TOV0
	rjmp	WAIT1		; if clear loop around
	dec 	counter1	; decrement counter
	brne	DELAY		; and loop more if not zero
	ret

DELAY1: ldi	counter1,1	; Entry point for aprox  1 ms sec delay
	ldi	temp,-1	
	rjmp	DENTR
DELAY5: ldi	counter1,1	; Entry point for aprox  5 ms sec delay
	ldi	temp,-5	
	rjmp	DENTR
DELAY50: ldi	counter1,1	; Entry point for aprox  50 ms sec delay
	ldi	temp,-50	
	rjmp	DENTR
DELAY250: ldi	counter1,1	; Entry point for aprox  1/4 sec delay
	rjmp	DELAY	; jump to delay
DELAY1sec: ldi	counter1,4	; Entry point for aprox  1 sec delay
	rjmp	DELAY	; jump to delay
DELAY80: ldi	counter1,1	; Entry point for aprox  80 ms delay
	ldi	temp,-80	
	rjmp	DENTR	; jump to delay
;---------------------------------------------------------------
shftmrg:
	in	matrixread,PIND	; read port d
	andi	matrixread,0x3	; mask out other bits
	lsl	switches
	lsl	switches
	or	switches,matrixread
	ret

readswt:	; read all of switch matrix and place in "switches"

testb4col:	; read supply tank mt and head overflow n/o  micro
	sbi	PORTD,PB4	; apply charging voltage to supply and overflow switches
	ldi	temp,0x1C
	out	DDRD,TEMP	; make other pins inputs
	rcall	DELAY5		; allow charging time
	rcall 	shftmrg 
	cbi	PORTD,PB4	; apply discharging voltage	
	ldi	temp,0x1f
	out	DDRD,TEMP	; make them all outputs again
	rjmp	DELAY50		; allow discharging time  and return
;--------------------------------------------------------------------
; IR pulsing routines
Tpulse: ; a series of 13 cyles with 16 uSec on and 15.25 uSec off.
	ldi	counter1,13	; 1 cycle
; led on time = counter2*3 + 2 + 1 + 1 + 1 + 1 + 1 = (C2-1)*3+7 
TPloop:	iron 			; 2 cycles
	nop			; 1 cycle
	ldi	counter2,4	; 1 cycle
TPondel:dec counter2		; 1 cycle decrement counter
	brne TPondel		; 1 or 2 cycles - and loop more if not zero
	ldi	counter2,4	; 1 cycle
; led off time = counter2*4 + 2 + 1 + 1 + 1 + 2= (C2-1)*3+6 

	iroff 			; 2 cycles
TPoffdel:dec counter2		; 1 cycle decrement counter
	brne TPoffdel		; 1 or 2 cycles - and loop more if not zero
	dec counter1		; 1 cycle - decrement counter
	brne TPloop		; 1 or 2 cycles - and loop more if not zero
;rjmp tploop	; 2
	ret			; 4 cycles
;-------
TTime:	ldi counter0,130	; 1 
Tdly1:	dec	counter0	; 1
	brne	Tdly1		; 2/1
	ret
;-------
sendcode:	; send the actual control code in codehi + codelo via IR led
	ldi	loopcnt,4 ; send code 4 times
lp1:	ldi	grp1,0x00
	ldi	grp2,0x09
	ldi	grp3,0x04
	ldi	grp4,0x40
	mov	codehi,cd1
	mov	codelo,cd2
	ldi	counter1,130	; 1 cycle
; led on time = counter2*3 + 2 + 1 + 1 + 1 + 1 + 1 = C2*3+7 = 16
Hdloop:	iron 			; 2 cycles
	ldi	counter2,4	; 1 cycle
Hdondel:dec counter2		; 1 cycle decrement counter
	brne Hdondel		; 1 or 2 cycles - and loop more if not zero
	ldi	counter2,4	; 1 cycle
	nop			; 1 cycle
; led off time = counter2*3 + 2 + 1 + 1 + 1 + 2= C2*3+6 = 15
	iroff 			; 2 cycles
Hdoffdel:dec counter2		; 1 cycle decrement counter
	brne Hdoffdel		; 1 or 2 cycles - and loop more if not zero
	dec counter1		; 1 cycle - decrement counter
	brne Hdloop		; 1 or 2 cycles - and loop more if not zero
;	rjmp hdloop
; header off period 1600 uSec
	rcall ttime
	rcall ttime
	rcall ttime
	rcall ttime
	
;	rjmp test
; now the fun stuff....
	ldi	counter3,48	; 1 cycle = setup for 48 bit code
; assume hibit first out for now!!!!!
shift:	rcall tpulse
	rol	codelo 		; 1 cycle - rotate pattern
	rol	codehi 		; 1 cycle - rotate pattern
	rol	grp1 		; 1 cycle - rotate pattern
	rol	grp2 		; 1 cycle - rotate pattern
	rol	grp3 		; 1 cycle - rotate pattern
	rol	grp4 		; 1 cycle - rotate pattern
	brcs	sendone		; 1 or 2 cycles - if carry send a "one"
sendzero:  rcall ttime
	rjmp	testc3
sendone: rcall ttime		 
	 rcall ttime
	 rcall ttime
testc3:	dec	counter3;
	brne	shift
	rcall tpulse	; terminate bit
	rcall delay80
	dec	loopcnt
	brne	lp1
	rjmp delay250
;	ret
	---------------------------------------------------------------
; code starts executing here on reset
RESET:	ldi	temp,(1<<CS02)+(0<<CS01)+(1<<CS00)
	out	TCCR0,temp	; Set timer clock to processor clock/1024 (slowest)
	sbi	DDRB,PB3	; Make B3 an output to drive FET

	ldi	temp,0x1f
	out	DDRD,temp	; port D pins 0-4 as outputs initially
	sbi	DDRB,PB6	; Enable led driver.
	ldi	temp,0		; clear temp
	out	PORTD,TEMP	; clear portd pins 0-4

LOOP:	rcall delay250
	ledon
	rcall readswt
	ledoff
	SBRS	switches,STMT	; if bit set goto record
	rjmp loop
record:	ledon
	lampson
	ldi cd1,0x08
	ldi cd2,0x01
	rcall sendcode		; select channel 1 to place vcr in "tuner" mode
	ldi cd1,0x03
	ldi cd2,0x0a
	rcall sendcode		; select other input to place vcr in "aux in " mode
	ldi cd1,0x10
	ldi cd2,0x19
	rcall sendcode		; send "record" code
	ldi rectimer,240
countdown:
	rcall delay1sec 
	rcall readswt
	SBRC	switches,STMT	; if bit clear no PIR event skip counter reload
	ldi rectimer,240	; reload timer
nopir:	dec rectimer
	brne	countdown
	ledoff	
	lampsoff
	ldi cd1,0x00
	ldi cd2,0x09
	rcall sendcode		; send "stop" code
	rjmp	LOOP
; that's all folks